FileMakerからMBSプラグインを利用してExcelファイルを作成する

MBSプラグイン

MBSプラグインを使用したExcelファイルの作成

MBS認証
# ##################################################
# MBSブラグインの認証
# ##################################################

# MBSプラグインが登録されていない場合は終了
変数を設定 [$plugin; 値: Get ( インストールされた FM プラグイン )]
If [PatternCount ( $plugin ; "MBS Plug-In" ) = 0]
	カスタムダイアログを表示 ["ERROR"; "MBSプラグインがインストールされていません¶インストール後、再起動して下さい"]
	ウインドウを閉じる [現在のウインドウ]
End If

# 認証済みなら処理不要
If [MBS( "IsRegistered" )]
	現在のスクリプト終了 [テキスト結果: ]
End If

# MBSプラグインの認証
変数を設定 [$Register; 値: MBS("Register"; authInfo::MBS_LicenseeName; authInfo::MBS_Component; authInfo::MBS_LicenseType; authInfo::MBS_ExpireMonth; authInfo::MBS_SerialNumber )]

LibXL認証
# ##################################################
# MBSプラグインのXL機能使用の為のDLL読み込み
# ##################################################

# LibXL認証済みなら処理不要
変数を設定 [$res; 値: MBS( "XL.IsInitialized" )]
If [$res]
	現在のスクリプト終了 [テキスト結果: ]
End If

# LibXLのDLLファイルが存在しない場合は終了
変数を設定 [$path; 値: Middle ( Get ( FileMaker パス ) ; 2 ; Length ( Get ( FileMaker パス ) ) - 1 ) & "Extensions/libxl.dll"]
If [not MBS( "Files.FileExists" ; $path )]
	カスタムダイアログを表示 ["ERROR"; "DLLの読み込みに失敗しました"]
	ウインドウを閉じる [現在のウインドウ]
End If

# LibXLの認証
変数を設定 [$Initialize; 値: MBS( "XL.Initialize"; authInfo::LibXL_LibPath; authInfo::LibXL_LicenseName; authInfo::LibXL_LicenseKey )]
If [$Initialize ≠ "OK"]
	カスタムダイアログを表示 ["ERROR"; "DLLの認証に失敗しました¶体験版で実行します"]
End If

Excel作成
# ##################################################
# Excelテンプレートへの流し込み
# ##################################################

スクリプト実行 [指定:一覧から;「MBS認証」; 引数: ]
スクリプト実行 [指定:一覧から;「LibXL認証」; 引数: ]

# テンプレートファイルを開く
変数を設定 [$xl; 値: MBS( "XL.LoadBook" ; data::テンプレート )]

# テキストの流し込み
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 3; 4; data::名前 )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 5; 4; data::ふりがな )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 7; 4; data::生年月日 )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 9; 4; data::血液型 )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 11; 4; data::趣味 )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 13; 4; data::特技 )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 19; 2; data::自己PR )]
変数を設定 [$res; 値: MBS( "XL.Sheet.CellWriteText"; $xl; 0; 28; 2; data::フリースペース )]

# 画像サイズと比率取得
変数を設定 [$baseWidth; 値: GetContainerAttribute ( data::写真; "width" )]
変数を設定 [$baseHeight; 値: GetContainerAttribute ( data::写真; "height" )]
変数を設定 [$ratio; 値: $baseHeight / $baseWidth]

# 画像配置
変数を設定 [$pictureID; 値: MBS( "XL.Book.AddPictureContainer"; $xl; data::写真 )]

# 配置セルのサイズ
変数を設定 [$width; 値: MBS( "XL.Sheet.GetColWidth"; $xl; 0; 16 ) * 9.43 * 6 - 2]
変数を設定 [$height; 値: MBS( "XL.Sheet.GetRowHeight"; $xl; 0; 3 ) * 4 / 3 * 8 - 2]

# 画像の比率に応じてリサイズ
If [$ratio > 1.293]
	変数を設定 [$res; MBS( "XL.Sheet.SetPictureWithSize"; $xl; 0; 3; 16; $pictureID; $height * $ratio; $height; ($width - $height * $ratio) / 2; 1; 0 )]
Else
	変数を設定 [$res; MBS( "XL.Sheet.SetPictureWithSize"; $xl; 0; 3; 16; $pictureID; $width; $width * $ratio; 1; ($height - $width * $ratio) / 2; 1 )]
End If

# 処理結果フィールドへエクセルファイルを保存
フィールド設定 [data::作成ファイル; MBS( "XL.Book.Save" ; $xl; "result.xlsx" )]

# エクセルファイルをメモリから解放する
変数を設定 [$res; MBS( "XL.Book.Release"; $xl )]

サンプルファイル

---